1 # Process this file with autoconf to produce a configure script.
2 
3 AC_PREREQ([2.69])
4 AC_INIT([got-portable], [0.75], [thomas@xteddy.org])
5 AC_CONFIG_AUX_DIR(etc)
6 AC_CONFIG_SRCDIR([lib/rcsutil.h])
7 AM_INIT_AUTOMAKE([foreign subdir-objects])
8 
9 GOT_RELEASE=No
10 
11 AC_DEFINE_UNQUOTED(VERSION, "$VERSION")
12 AC_SUBST(VERSION)
13 AC_SUBST(GOT_RELEASE)
14 
15 AC_CANONICAL_HOST
16 
17 # When CFLAGS isn't set at this stage and gcc is detected by the macro below,
18 # autoconf will automatically use CFLAGS="-O2 -g". Prevent that by using an
19 # empty default.
20 : ${CFLAGS=""}
21 
22 # Save user CPPFLAGS, CFLAGS and LDFLAGS. We need to change them because
23 # AC_CHECK_HEADER doesn't give us any other way to update the include
24 # paths. But for Makefile.am we want to use AM_CPPFLAGS and friends.
25 SAVED_CFLAGS="$CFLAGS"
26 SAVED_CPPFLAGS="$CPPFLAGS"
27 SAVED_LDFLAGS="$LDFLAGS"
28 
29 # Checks for programs.
30 AC_PROG_CC
31 AC_PROG_CPP
32 AC_PROG_INSTALL
33 AC_PROG_LN_S
34 AC_PROG_MAKE_SET
35 AC_PROG_YACC
36 AC_PROG_RANLIB
37 PKG_PROG_PKG_CONFIG
38 AC_USE_SYSTEM_EXTENSIONS
39 
40 # Checks for header files.
41 AC_CHECK_HEADERS([ \
42 	fcntl.h \
43 	langinfo.h \
44 	limits.h \
45 	linux/landlock.h \
46 	locale.h \
47 	netdb.h \
48 	netinet/in.h \
49 	paths.h \
50 	poll.h \
51 	stddef.h \
52 	stdint.h \
53 	stdlib.h \
54 	string.h \
55 	sys/ioctl.h \
56 	sys/param.h \
57 	sys/poll.h \
58 	sys/socket.h \
59 	sys/time.h \
60 	sys/tree.h \
61 	tls.h \
62 	util.h \
63 	unistd.h \
64 	wchar.h \
65 ])
66 
67 # Checks for typ edefs, structures, and compiler characteristics.
68 AC_CHECK_HEADER_STDBOOL
69 AC_C_INLINE
70 AC_TYPE_INT64_T
71 AC_TYPE_MODE_T
72 AC_TYPE_OFF_T
73 AC_TYPE_PID_T
74 AC_TYPE_SIZE_T
75 AC_TYPE_SSIZE_T
76 AC_TYPE_UINT16_T
77 AC_TYPE_UINT32_T
78 AC_TYPE_UINT64_T
79 AC_TYPE_UINT8_T
80 
81 # Check for ifgroupreq which is only available on BSD.
82 AC_CHECK_TYPES([struct ifgroupreq])
83 
84 # Look for library needed for flock.
85 AC_SEARCH_LIBS(flock, bsd)
86 
87 # Checks for library functions.
88 AC_FUNC_FORK
89 AC_FUNC_FSEEKO
90 AC_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK
91 AC_FUNC_MALLOC
92 AC_FUNC_MMAP
93 AC_FUNC_REALLOC
94 AC_FUNC_STRERROR_R
95 AC_FUNC_STRNLEN
96 AC_CHECK_FUNCS([ \
97 	dup2 \
98 	flock \
99 	getcwd \
100 	localtime_r \
101 	memchr \
102 	memmove \
103 	memset \
104 	mkdir \
105 	munmap \
106 	nl_langinfo \
107 	realpath \
108 	regcomp \
109 	rmdir \
110 	setlocale \
111 	socket \
112 	setresgid \
113 	setresuid \
114 	setproctitle \
115 	strcasecmp \
116 	strchr \
117 	strcspn \
118 	strdup \
119 	strerror \
120 	strlcpy \
121 	strncasecmp \
122 	strndup \
123 	strrchr \
124 	strspn \
125 	strstr \
126 	strtol \
127 	strtoul \
128 	wcwidth \
129 ])
130 
131 AM_CONDITIONAL([HAVE_SETPROCTITLE], [test "x$ac_cv_func_setproctitle" = xyes])
132 AM_CONDITIONAL([HAVE_SETRESGID], [test "x$ac_cv_func_setresgid" = xyes])
133 AM_CONDITIONAL([HAVE_SETRESUID], [test "x$ac_cv_func_setresuid" = xyes])
134 
135 # Siphash support.
136 AC_CHECK_FUNCS([SipHash])
137 AM_CONDITIONAL([HAVE_SIPHASH], [test "x$ac_cv_func_SipHash" = xyes])
138 
139 # Check for functions with a compatibility implementation.
140 AC_REPLACE_FUNCS([ \
141 	asprintf \
142 	closefrom \
143 	explicit_bzero \
144 	fmt_scaled \
145 	freezero \
146 	getdtablecount \
147 	getline \
148 	getprogname \
149 	recallocarray \
150 	reallocarray \
151 	strlcat \
152 	strlcpy \
153 	strndup \
154 	strsep \
155 	strtonum \
156 ])
157 
158 # Always use our getopt because 1) glibc's doesn't enforce argument order 2)
159 # musl does not set optarg to NULL for flags without arguments (although it is
160 # not required to, but it is helpful) 3) there are probably other weird
161 # implementations.
162 AC_LIBOBJ(getopt)
163 
164 # Check the platform we're compiling on.
165 AC_MSG_CHECKING(platform)
166 case "$host_os" in
167 	*linux*)
168 		AC_MSG_RESULT(linux)
169 		PLATFORM=linux
170 		;;
171 	*freebsd*)
172 		AC_MSG_RESULT(freebsd)
173 		PLATFORM=freebsd
174 		;;
175 	*darwin*)
176 		AC_MSG_RESULT(darwin)
177 		PLATFORM=darwin
178 		;;
179 	*netbsd*)
180 		AC_MSG_RESULT(netbsd)
181 		PLATFORM=netbsd
182 		;;
183 	*dragonfly*)
184 		AC_MSG_RESULT(dragonfly)
185 		PLATFORM=dragonflybsd
186 		;;
187 	*)
188 		AC_MSG_RESULT(unknown)
189 		PLATFORM=unknown
190 		;;
191 esac
192 AC_SUBST(PLATFORM)
193 AM_CONDITIONAL([HOST_FREEBSD], [test "$PLATFORM" = "freebsd"])
194 AM_CONDITIONAL([HOST_LINUX], [test "$PLATFORM" = "linux"])
195 AM_CONDITIONAL([HOST_DARWIN], [test "$PLATFORM" = "darwin"])
196 AM_CONDITIONAL([HOST_NETBSD], [test "$PLATFORM" = "netbsd"])
197 AM_CONDITIONAL([HOST_DRAGONFLYBSD], [test "$PLATFORM" = "dragonflybsd"])
198 
199 # Landlock detection.
200 AC_MSG_CHECKING([for landlock])
201 AM_CONDITIONAL([HAVE_LINUX_LANDLOCK],
202     [test "x$ac_cv_header_linux_landlock_h" = "xyes"])
203 if test "x$ac_cv_header_linux_landlock_h" = "xyes"; then
204 	AC_MSG_RESULT(yes)
205 else
206 	AC_MSG_RESULT(no)
207 fi
208 
209 # Clang sanitizers wrap reallocarray even if it isn't available on the target
210 # system. When compiled it always returns NULL and crashes the program. To
211 # detect this we need a more complicated test.
212 AC_MSG_CHECKING([for working reallocarray])
213 AC_RUN_IFELSE([AC_LANG_PROGRAM(
214 		[#include <stdlib.h>],
215 		[return (reallocarray(NULL, 1, 1) == NULL);]
216 	)],
217 	AC_MSG_RESULT(yes),
218 	[AC_LIBOBJ(reallocarray) AC_MSG_RESULT([no])],
219 	[AC_LIBOBJ(reallocarray) AC_MSG_RESULT([no])]
220 )
221 AC_MSG_CHECKING([for working recallocarray])
222 AC_RUN_IFELSE([AC_LANG_PROGRAM(
223 		[#include <stdlib.h>],
224 		[return (recallocarray(NULL, 1, 1, 1) == NULL);]
225 	)],
226 	AC_MSG_RESULT(yes),
227 	[AC_LIBOBJ(recallocarray) AC_MSG_RESULT([no])],
228 	[AC_LIBOBJ(recallocarray) AC_MSG_RESULT([no])]
229 )
230 
231 # Look for imsg_init in libutil.
232 AC_SEARCH_LIBS(imsg_init, util, found_imsg_init=yes, found_imsg_init=no)
233 if test "x$found_imsg_init" = xyes; then
234 	AC_DEFINE(HAVE_IMSG)
235 else
236 	AC_LIBOBJ(imsg)
237 	AC_LIBOBJ(imsg-buffer)
238 fi
239 
240 # libevent (for gotwebd).  Lifted from tmux.
241 # Look for libevent. Try libevent_core or libevent with pkg-config first then
242 # look for the library.
243 PKG_CHECK_MODULES(
244 	LIBEVENT_CORE,
245 	[libevent_core >= 2],
246 	[
247 		AM_CPPFLAGS="$LIBEVENT_CORE_CFLAGS $AM_CPPFLAGS"
248 		CPPFLAGS="$AM_CPPFLAGS $SAVED_CPPFLAGS"
249 		LIBS="$LIBEVENT_CORE_LIBS $LIBS"
250 		found_libevent=yes
251 	],
252 	found_libevent=no
253 )
254 if test x$found_libevent = xno; then
255 	PKG_CHECK_MODULES(
256 		LIBEVENT,
257 		[libevent >= 2],
258 		[
259 			AM_CPPFLAGS="$LIBEVENT_CFLAGS $AM_CPPFLAGS"
260 			CPPFLAGS="$AM_CPPFLAGS $SAVED_CPPFLAGS"
261 			LIBS="$LIBEVENT_LIBS $LIBS"
262 			found_libevent=yes
263 		],
264 		found_libevent=no
265 	)
266 fi
267 if test x$found_libevent = xno; then
268 	AC_SEARCH_LIBS(
269 		event_init,
270 		[event_core event event-1.4],
271 		found_libevent=yes,
272 		found_libevent=no
273 	)
274 fi
275 AC_CHECK_HEADER(
276 	event2/event.h,
277 	AC_DEFINE(HAVE_EVENT2_EVENT_H),
278 	[
279 		AC_CHECK_HEADER(
280 			event.h,
281 			AC_DEFINE(HAVE_EVENT_H),
282 			found_libevent=no
283 		)
284 	]
285 )
286 if test "x$found_libevent" = xno; then
287 	AC_MSG_ERROR("libevent not found")
288 fi
289 
290 # libcrypto (via libssl for SHA information)
291 PKG_CHECK_MODULES(
292 	LIBCRYPTO,
293 	libcrypto,
294 	[
295 	 	AM_CFLAGS="$LIBCRYPTO_CFLAGS $AM_CFLAGS"
296 		CFLAGS="$AM_CFLAGS $SAVED_CFLAGS"
297 		LIBS="$LIBCRYPTO_LIBS $LIBS"
298 		found_libcrypto=yes
299 	],
300 	[
301 	 	found_libcrypto=no
302 	]
303 )
304 
305 if test "x$found_libcrypto" = "xyes"; then
306 	AC_DEFINE(HAVE_LIBCRYPTO)
307 fi
308 
309 AC_SEARCH_LIBS(uuid_create, , AC_DEFINE(HAVE_BSD_UUID))
310 AC_SEARCH_LIBS(uuid_create, found_uuid=no, found_uuid=yes)
311 AC_SEARCH_LIBS(mergesort, , AC_DEFINE(HAVE_BSD_MERGESORT))
312 
313 # Don't define HAVE_BSD_UUID on darwin (Apple) as this breaks the BSD API.
314 # Instead, use the UUID implementation wrapper that's in compat/ plus uuid
315 # ossp
316 if test "x$found_uuid" = "xyes" -a "x$PLATFORM" != "darwin"; then
317 	AC_DEFINE(HAVE_BSD_UUID)
318 else
319 	PKG_CHECK_MODULES(
320 		LIBUUID,
321 		uuid,
322 		[
323 			AM_CFLAGS="$LIBUUID_CFLAGS $AM_CFLAGS"
324 			CFLAGS="$AM_CFLAGS $SAVED_CFLAGS"
325 			LIBS="$LIBUUID_LIBS $LIBS"
326 			found_libuuid=yes
327 		],
328 		[
329 			found_libuuid=no
330 		]
331 	)
332 
333 	if test "x$found_libuuid" = "xno"; then
334 		AC_CHECK_HEADER(
335 			uuid.h,
336 			found_libuuid=yes,
337 			found_libuuid=no)
338 	fi
339 fi
340 
341 if test "x$found_libuuid" = "xno"; then
342 	AC_MSG_ERROR("*** couldn't find uuid ***")
343 fi
344 
345 PKG_CHECK_MODULES(
346 	ZLIB,
347 	zlib,
348 	[
349 	 	AM_CFLAGS="$ZLIB_CFLAGS $AM_CFLAGS"
350 		CFLAGS="$AM_CFLAGS $SAVED_CFLAGS"
351 		LIBS="$ZLIB_LIBS $LIBS"
352 		found_zlib=yes
353 	],
354 	[
355 	 	found_zlib=no
356 	]
357 )
358 
359 if test "x$found_zlib" = "xno"; then
360 	AC_CHECK_HEADER(
361 		zlib.h,
362 		,
363 		found_zlib=no)
364 fi
365 
366 if test "x$found_zlib" = "xno"; then
367 	AC_MSG_ERROR("*** couldn't find zlib ***")
368 fi
369 
370 if test "$PLATFORM" = "linux"; then
371 	PKG_CHECK_MODULES(
372 		LIBMD,
373 		libmd,
374 		[
375 			AM_CFLAGS="$LIBMD_CFLAGS $AM_CFLAGS"
376 			CFLAGS="$AM_CFLAGS $SAVED_CFLAGS"
377 			LIBS="$LIBMD_LIBS $LIBS"
378 		],
379 		[
380 			AC_MSG_ERROR("*** couldn't find libmd via pkg-config")
381 		]
382 	)
383 	PKG_CHECK_MODULES(
384 		LIBBSD,
385 		libbsd-overlay,
386 		[
387 			AM_CFLAGS="$LIBBSD_CFLAGS $AM_CFLAGS"
388 			CFLAGS="$AM_CFLAGS $SAVED_CFLAGS"
389 			LIBS="$LIBBSD_LIBS $LIBS"
390 			found_libbsd=yes
391 			AC_DEFINE(HAVE_LIBBSD)
392 		],
393 		[]
394 	)
395 fi
396 
397 # Look for a suitable queue.h.  We hope libbsd is enough, but that is missing
398 # SIMPLEQ.
399 AC_CHECK_DECL(
400 	SIMPLEQ_INIT,
401 	found_queue_h=yes,
402 	found_queue_h=no,
403 	[#include <sys/queue.h>]
404 )
405 AC_CHECK_DECL(
406 	TAILQ_CONCAT,
407 	found_queue_h=yes,
408 	found_queue_h=no,
409 	[#include <sys/queue.h>]
410 )
411 AC_CHECK_DECL(
412 	TAILQ_PREV,
413 	found_queue_h=yes,
414 	found_queue_h=no,
415 	[#include <sys/queue.h>]
416 )
417 AC_CHECK_DECL(
418 	TAILQ_REPLACE,
419 	found_queue_h=yes,
420 	found_queue_h=no,
421 	[#include <sys/queue.h>]
422 )
423 AC_CHECK_DECL(
424 	SIMPLEQ_ENTRY,
425 	,
426 	found_queue_h=no,
427 	[#include <sys/queue.h>]
428 )
429 AC_CHECK_DECL(
430 	TAILQ_FOREACH_SAFE,
431 	,
432 	found_queue_h=no,
433 	[#include <sys/queue.h>]
434 )
435 if test "x$found_queue_h" = xyes; then
436 	AC_DEFINE(HAVE_QUEUE_H)
437 fi
438 
439 # Look for __progname.
440 AC_MSG_CHECKING(for __progname)
441 AC_LINK_IFELSE([AC_LANG_SOURCE(
442 	[
443 		#include <stdio.h>
444 		#include <stdlib.h>
445 		extern char *__progname;
446 		int main(void) {
447 			const char *cp = __progname;
448 			printf("%s\n", cp);
449 			exit(0);
450 		}
451 	])],
452 	[AC_DEFINE(HAVE___PROGNAME) AC_MSG_RESULT(yes)],
453 	AC_MSG_RESULT(no)
454 )
455 
456 PKG_CHECK_MODULES(
457 	LIBPANELW,
458 	panelw,
459 	found_panel=yes,
460 	found_panel=no
461 )
462 
463 PKG_CHECK_MODULES(
464 	LIBPANELW,
465 	gnupanelw,
466 	found_panel=yes,
467 	found_panel=no
468 )
469 
470 PKG_CHECK_MODULES(
471 	LIBPANELW,
472 	panel,
473 	found_panel=yes,
474 	found_panel=no
475 )
476 if test "x$found_panel" = "xno"; then
477 	AC_CHECK_LIB(panelw, update_panels,,
478 		AC_MSG_ERROR([ "*** panelw not found for ncurses. ***"])
479 	)
480 
481 	LIBPANELW_LIBS="-lpanelw"
482 fi
483 
484 PKG_CHECK_MODULES(
485 	LIBNCURSES,
486 	ncursesw,
487 	found_ncurses=yes,
488 	found_ncurses=no
489 )
490 if test "x$found_ncurses" = xyes; then
491 	AM_CFLAGS="$LIBNCURSES_CFLAGS $LIBTINFO_CFLAGS $LIBPANELW_CFLAGS $AM_CFLAGS"
492 	CFLAGS="$LIBNCURSES_CFLAGS $LIBTINFO_CFLAGS $LIBPANELW_CFLAGS $CFLAGS"
493 	LIBS="$LIBNCURSES_LIBS $LIBTINFO_LIBS $LIBPANELW_LIBS $LIBS"
494 else
495 	AC_CHECK_LIB(
496 		ncursesw,
497 		setupterm,
498 		found_ncurses=yes,
499 		found_ncurses=no
500 	)
501 	if test "x$found_ncurses" = xyes; then
502 		AC_CHECK_HEADER(
503 			ncurses.h,
504 			AM_CFLAGS="$LIBPANELW_CFLAGS $AM_CFLAGS"
505 			CFLAGS="$LIBPANEL_CFLAGS $CFLAGS"
506 			LIBS="$LIBS -lncursesw $LIBPANELW_LIBS",
507 			found_ncurses=no
508 		)
509 	fi
510 fi
511 if test "x$found_ncurses" = xyes; then
512 	AC_DEFINE(HAVE_NCURSES_H)
513 else
514 	# No ncurses, try curses.
515 	AC_CHECK_LIB(
516 		cursesw,
517 		setupterm,
518 		found_curses=yes,
519 		found_curses=no
520 	)
521 	AC_CHECK_HEADER(
522 		curses.h,
523 		,
524 		found_curses=no)
525 	if test "x$found_curses" = xyes; then
526 		AM_CFLAGS="$LIBPANELW_CFLAGS $AM_CFLAGS"
527 		CFLAGS="$LIBPANEL_CFLAGS $CFLAGS"
528 		LIBS="$LIBS -lcursesw $LIBPANELW_LIBS"
529 		AC_DEFINE(HAVE_CURSES_H)
530 	else
531 		AC_MSG_ERROR("curses not found")
532 	fi
533 fi
534 
535 # Save our CFLAGS/CPPFLAGS/LDFLAGS for the Makefile and restore the old user
536 # variables.
537 AC_SUBST(AM_CPPFLAGS)
538 CPPFLAGS="$SAVED_CPPFLAGS"
539 AC_SUBST(AM_CFLAGS)
540 CFLAGS="$SAVED_CFLAGS"
541 AC_SUBST(AM_LDFLAGS)
542 LDFLAGS="$SAVED_LDFLAGS"
543 
544 AC_CONFIG_FILES([Makefile
545 		 compat/Makefile
546 		 libexec/Makefile
547 		 libexec/got-read-tree/Makefile
548 		 libexec/got-fetch-pack/Makefile
549 		 libexec/got-index-pack/Makefile
550 		 libexec/got-read-blob/Makefile
551 		 libexec/got-read-commit/Makefile
552 		 libexec/got-read-gitconfig/Makefile
553 		 libexec/got-read-gotconfig/Makefile
554 		 libexec/got-read-object/Makefile
555 		 libexec/got-read-pack/Makefile
556 		 libexec/got-read-patch/Makefile
557 		 libexec/got-read-tag/Makefile
558 		 libexec/got-send-pack/Makefile
559 		 got/Makefile
560 		 gotadmin/Makefile
561 		 gotwebd/Makefile
562 		 tog/Makefile
563 		 Makefile.common:Makefile.common.in])
564 AC_OUTPUT
565 
566 #                tog/GNUMakefile])
567 #                regress/GNUMakefile
568 #                regress/cmdline/GNUMakefile
569 #                regress/delta/GNUMakefile
570 #                regress/fetch/GNUMakefile
571 #                regress/idset/GNUMakefile
572 #                regress/path/GNUMakefile
573 #                 gotweb/GNUMakefile
574 #                 gotweb/libexec/GNUMakefile
575 #                 gotweb/libexec/got-read-blob/GNUMakefile
576 #                 gotweb/libexec/got-read-commit/GNUMakefile
577 #                 gotweb/libexec/got-read-gitconfig/GNUMakefile
578 #                 gotweb/libexec/got-read-gotconfig/GNUMakefile
579 #                 gotweb/libexec/got-read-object/GNUMakefile
580 #                 gotweb/libexec/got-read-pack/GNUMakefile
581 #                 gotweb/libexec/got-read-tag/GNUMakefile
582 #                 gotweb/libexec/got-read-tree/GNUMakefile