1 # Process this file with autoconf to produce a configure script.
2 
3 AC_PREREQ([2.69])
4 AC_INIT([got-portable],
5 	m4_esyscmd_s(util/got-portable-ver.sh),
6 	[thomas@xteddy.org])
7 AC_CONFIG_AUX_DIR(etc)
8 AC_CONFIG_SRCDIR([lib/rcsutil.h])
9 AM_INIT_AUTOMAKE([foreign subdir-objects])
10 
11 AC_DEFINE_UNQUOTED(VERSION, "$VERSION")
12 AC_SUBST(VERSION)
13 AC_SUBST(GOT_RELEASE)
14 
15 AC_USE_SYSTEM_EXTENSIONS
16 AC_CANONICAL_HOST
17 
18 # When CFLAGS isn't set at this stage and gcc is detected by the macro below,
19 # autoconf will automatically use CFLAGS="-O2 -g". Prevent that by using an
20 # empty default.
21 : ${CFLAGS=""}
22 
23 # Save user CPPFLAGS, CFLAGS and LDFLAGS. We need to change them because
24 # AC_CHECK_HEADER doesn't give us any other way to update the include
25 # paths. But for Makefile.am we want to use AM_CPPFLAGS and friends.
26 SAVED_CFLAGS="$CFLAGS"
27 SAVED_CPPFLAGS="$CPPFLAGS"
28 SAVED_LDFLAGS="$LDFLAGS"
29 
30 # Checks for programs.
31 AC_PROG_CC
32 AC_PROG_CPP
33 AC_PROG_INSTALL
34 AC_PROG_LN_S
35 AC_PROG_MAKE_SET
36 AC_PROG_YACC
37 AM_PROG_AR
38 AC_PROG_RANLIB
39 PKG_PROG_PKG_CONFIG
40 
41 # Checks for header files.
42 AC_CHECK_HEADERS([ \
43 	fcntl.h \
44 	langinfo.h \
45 	limits.h \
46 	linux/landlock.h \
47 	locale.h \
48 	netdb.h \
49 	netinet/in.h \
50 	paths.h \
51 	poll.h \
52 	stddef.h \
53 	stdint.h \
54 	stdlib.h \
55 	string.h \
56 	sys/ioctl.h \
57 	sys/param.h \
58 	sys/poll.h \
59 	sys/queue.h \
60 	sys/socket.h \
61 	sys/time.h \
62 	sys/tree.h \
63 	util.h \
64 	unistd.h \
65 	wchar.h \
66 ])
67 
68 # Checks for typ edefs, structures, and compiler characteristics.
69 AC_CHECK_HEADER_STDBOOL
70 AC_C_INLINE
71 AC_TYPE_INT64_T
72 AC_TYPE_MODE_T
73 AC_TYPE_OFF_T
74 AC_TYPE_PID_T
75 AC_TYPE_SIZE_T
76 AC_TYPE_SSIZE_T
77 AC_TYPE_UINT16_T
78 AC_TYPE_UINT32_T
79 AC_TYPE_UINT64_T
80 AC_TYPE_UINT8_T
81 
82 # Check for ifgroupreq which is only available on BSD.
83 AC_CHECK_TYPES([struct ifgroupreq])
84 
85 # Check for sockaddr_storage.  On some systems, ss_len is filled out, although
86 # this is not mandated by POSIX, and hence systems such as linux, don't have
87 # it.
88 AC_CHECK_TYPES([struct sockaddr_storage], [], [], [
89 #include <sys/types.h>
90 #include <sys/socket.h>
91 ])
92 
93 # Same thing as sockaddr_storage above, only now check if the member exists in
94 # the struct as well.
95 AC_CHECK_MEMBERS([struct sockaddr_storage.ss_len], , ,
96 	[ #include <netdb.h>
97 	  #include <netinet/in.h>
98 	  #include <sys/socket.h> ]
99 )
100 
101 AC_CHECK_MEMBERS([struct sockaddr.sa_len], , ,
102 	[ #include <netdb.h>
103 	  #include <netinet/in.h>
104 	  #include <sys/socket.h> ]
105 )
106 
107 # Both checks above will result in:
108 #
109 # HAVE_STRUCT_SOCKADDR_AS_LEN
110 # SS_LEN
111 #
112 # Either being defined or not.
113 
114 # Look for library needed for flock.
115 AC_SEARCH_LIBS(flock, bsd)
116 
117 # Checks for library functions.
118 AC_FUNC_FORK
119 AC_FUNC_FSEEKO
120 AC_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK
121 AC_FUNC_MALLOC
122 AC_FUNC_MMAP
123 AC_FUNC_REALLOC
124 AC_FUNC_STRERROR_R
125 AC_FUNC_STRNLEN
126 AC_CHECK_FUNCS([ \
127 	dup2 \
128 	flock \
129 	getcwd \
130 	localtime_r \
131 	memchr \
132 	memmove \
133 	memset \
134 	mkdir \
135 	munmap \
136 	nl_langinfo \
137 	realpath \
138 	regcomp \
139 	rmdir \
140 	setlocale \
141 	socket \
142 	setresgid \
143 	setresuid \
144 	setproctitle \
145 	strcasecmp \
146 	strchr \
147 	strcspn \
148 	strdup \
149 	strerror \
150 	strlcpy \
151 	strncasecmp \
152 	strndup \
153 	strrchr \
154 	strspn \
155 	strstr \
156 	strtol \
157 	strtoul \
158 	wcwidth \
159 ])
160 
161 AM_CONDITIONAL([HAVE_SETPROCTITLE], [test "x$ac_cv_func_setproctitle" = xyes])
162 AM_CONDITIONAL([HAVE_SETRESGID], [test "x$ac_cv_func_setresgid" = xyes])
163 AM_CONDITIONAL([HAVE_SETRESUID], [test "x$ac_cv_func_setresuid" = xyes])
164 
165 # Siphash support.
166 AC_CHECK_FUNCS([SipHash])
167 AM_CONDITIONAL([HAVE_SIPHASH], [test "x$ac_cv_func_SipHash" = xyes])
168 
169 # Check for functions with a compatibility implementation.
170 AC_REPLACE_FUNCS([ \
171 	asprintf \
172 	closefrom \
173 	explicit_bzero \
174 	fmt_scaled \
175 	freezero \
176 	getdtablecount \
177 	getline \
178 	getprogname \
179 	recallocarray \
180 	reallocarray \
181 	strlcat \
182 	strlcpy \
183 	strndup \
184 	strsep \
185 	strtonum \
186 ])
187 
188 # Always use our getopt because 1) glibc's doesn't enforce argument order 2)
189 # musl does not set optarg to NULL for flags without arguments (although it is
190 # not required to, but it is helpful) 3) there are probably other weird
191 # implementations.
192 AC_LIBOBJ(getopt)
193 
194 # Check the platform we're compiling on.
195 AC_MSG_CHECKING(platform)
196 case "$host_os" in
197 	*linux*)
198 		AC_MSG_RESULT(linux)
199 		PLATFORM=linux
200 		;;
201 	*freebsd*)
202 		AC_MSG_RESULT(freebsd)
203 		PLATFORM=freebsd
204 		;;
205 	*darwin*)
206 		AC_MSG_RESULT(darwin)
207 		PLATFORM=darwin
208 		;;
209 	*netbsd*)
210 		AC_MSG_RESULT(netbsd)
211 		PLATFORM=netbsd
212 		;;
213 	*dragonfly*)
214 		AC_MSG_RESULT(dragonfly)
215 		PLATFORM=dragonflybsd
216 		;;
217 	*)
218 		AC_MSG_RESULT(unknown)
219 		PLATFORM=unknown
220 		;;
221 esac
222 AC_SUBST(PLATFORM)
223 AM_CONDITIONAL([HOST_FREEBSD], [test "$PLATFORM" = "freebsd"])
224 AM_CONDITIONAL([HOST_LINUX], [test "$PLATFORM" = "linux"])
225 AM_CONDITIONAL([HOST_DARWIN], [test "$PLATFORM" = "darwin"])
226 AM_CONDITIONAL([HOST_NETBSD], [test "$PLATFORM" = "netbsd"])
227 AM_CONDITIONAL([HOST_DRAGONFLYBSD], [test "$PLATFORM" = "dragonflybsd"])
228 
229 if test x"$PLATFORM" = "xdarwin"; then
230 	# Check for and/or set HOMEBREW_PREFIX.  brew is a common way of
231 	# installing applications.  The other is MacPorts.
232 	#
233 	# Before Apple Silicon existed (M1 onward), the paths for applications
234 	# installed via homebrew was typically /usr/local.  However, with M1
235 	# onward, this changed to a different path.
236 	#
237 	# Rather than hardcode this, check for HOMEBREW_PREFIX in the
238 	# environment if it's already set, and use it.  Otherwise, check for
239 	# brew(1) and use that.  If that fails, default to /usr/local
240 	#
241 	# This also means that MacPorts should continue to work.
242 	#
243 	# But with MacPorts, we should also check --prefix, and use that if it
244 	# has been supplied.
245 	#
246 	# In both cases, the variable HOMEBREW_PREFIX is used for both.
247 	HB_PREFIX=""
248 	FOUND_BISON="no"
249 	GNUBISON=""
250 	if test -z "$HOMEBREW_PREFIX" -o "$HOMEBREW_PREFIX" = "NONE"; then
251 		# HOMEBREW_PREFIX not set, check for brew(1)
252 		if command -v brew >/dev/null 2>&1; then
253 			AC_MSG_NOTICE("HOMEBREW_PREFIX set via 'brew --prefix'")
254 			export HOMEBREW_PREFIX="$(brew --prefix)"
255 		fi
256 
257 		if test -z "$HOMEBREW_PREFIX" -o "$HOMEBREW_PREFIX" = "NONE"
258 		then
259 			# Default.
260 			if test -z "${prefix}" -o "${prefix}" = "NONE"; then
261 				export HOMEBREW_PREFIX="/usr/local"
262 				HB_PREFIX="/usr/local"
263 				AC_MSG_NOTICE("HOMEBREW_PREFIX defaulting to $HB_PREFIX")
264 			else
265 				HB_PREFIX="$(eval echo ${prefix})"
266 				if test "$HB_PREFIX" = "NONE"; then
267 					HB_PREFIX="/opt/local"
268 				else
269 					AC_MSG_NOTICE("HOMEBREW_PREFIX using --prefix")
270 				fi
271 				export HOMEBREW_PREFIX="$HB_PREFIX"
272 			fi
273 		fi
274 	fi
275 
276 	AC_MSG_NOTICE("HOMEBREW_PREFIX determined as: $HOMEBREW_PREFIX")
277 
278 	if ! test -x "${HOMEBREW_PREFIX}/opt/bison/bin/bison"; then
279 		AC_MSG_WARN([
280 			     "***********************************************************
281 			     GNU Bison not found: ${HOMEBREW_PREFIX}/opt/bison/bin/bison
282 			     ***********************************************************
283 
284 			     Falling back to checking either /usr/local or \${prefix}"
285 		])
286 
287 		FOUND_BISON="no"
288 		AC_MSG_WARN("Trying ${HB_PREFIX}/opt/bison/bin/bison")
289 		if test -x "${HB_PREFIX}/opt/bison/bin/bison"; then
290 			export HOMEBREW_PREFIX="/usr/local"
291 			FOUND_BISON="yes"
292 			GNUBISON="${HB_PREFIX}/opt/bison/bin/bison"
293 		fi
294 
295 		if test "$FOUND_BISON" = "no"; then
296 			HB_PREFIX="/opt/local"
297 			AC_MSG_WARN("Trying ${HB_PREFIX}/bin/bison")
298 
299 			if test -x "${HB_PREFIX}/bin/bison"; then
300 				export HOMEBREW_PREFIX="${HB_PREFIX}"
301 				GNUBISON="${HB_PREFIX}/bin/bison"
302 				FOUND_BISON="yes"
303 			fi
304 		fi
305 	else
306 		FOUND_BISON="yes"
307 		GNUBISON="${HOMEBREW_PREFIX}/opt/bison/bin/bison"
308 	fi
309 
310 	if test "$FOUND_BISON" = "no"; then
311 		AC_MSG_ERROR("*** Couldn't find GNU BISON ***")
312 	fi
313 
314 	AC_MSG_NOTICE("Found GNU Bison as: $GNUBISON")
315 
316 	# Override YACC here to point to the GNU version of bison.
317 	export YACC="${GNUBISON} -y"
318 	export LDFLAGS="-L${HOMEBREW_PREFIX}/opt/ncurses/lib -L${HOMEBREW_PREFIX}/opt/openssl@3/lib $LDFLAGS"
319 	export CPPFLAGS="-I${HOMEBREW_PREFIX}/opt/ncurses/include -I${HOMEBREW_PREFIX}/opt/openssl@3/include $CPPFLAGS"
320 	export PKG_CONFIG_PATH="${HOMEBREW_PREFIX}/opt/ncurses/lib/pkgconfig"
321 	export PKG_CONFIG_PATH="$PKG_CONFIG_PATH:${HOMEBREW_PREFIX}/opt/openssl@3/lib/pkgconfig"
322 fi
323 
324 # Landlock detection.
325 AC_MSG_CHECKING([for landlock])
326 AM_CONDITIONAL([HAVE_LINUX_LANDLOCK],
327     [test "x$ac_cv_header_linux_landlock_h" = "xyes"])
328 if test "x$ac_cv_header_linux_landlock_h" = "xyes"; then
329 	AC_MSG_RESULT(yes)
330 else
331 	AC_MSG_RESULT(no)
332 fi
333 
334 # Clang sanitizers wrap reallocarray even if it isn't available on the target
335 # system. When compiled it always returns NULL and crashes the program. To
336 # detect this we need a more complicated test.
337 AC_MSG_CHECKING([for working reallocarray])
338 AC_RUN_IFELSE([AC_LANG_PROGRAM(
339 		[#include <stdlib.h>],
340 		[return (reallocarray(NULL, 1, 1) == NULL);]
341 	)],
342 	AC_MSG_RESULT(yes),
343 	[AC_LIBOBJ(reallocarray) AC_MSG_RESULT([no])],
344 	[AC_LIBOBJ(reallocarray) AC_MSG_RESULT([no])]
345 )
346 AC_MSG_CHECKING([for working recallocarray])
347 AC_RUN_IFELSE([AC_LANG_PROGRAM(
348 		[#include <stdlib.h>],
349 		[return (recallocarray(NULL, 1, 1, 1) == NULL);]
350 	)],
351 	AC_MSG_RESULT(yes),
352 	[AC_LIBOBJ(recallocarray) AC_MSG_RESULT([no])],
353 	[AC_LIBOBJ(recallocarray) AC_MSG_RESULT([no])]
354 )
355 
356 # Look for imsg_init in libutil.
357 AC_SEARCH_LIBS(imsg_init, util, found_imsg_init=yes, found_imsg_init=no)
358 AM_CONDITIONAL([HAVE_IMSG], [test "x$found_imsg_init" = "xyes"])
359 if test "x$found_imsg_init" = xno; then
360 	AC_LIBOBJ(imsg)
361 	AC_LIBOBJ(imsg-buffer)
362 fi
363 
364 # libevent (for gotwebd).  Lifted from tmux.
365 # Look for libevent. Try libevent_core or libevent with pkg-config first then
366 # look for the library.
367 PKG_CHECK_MODULES(
368 	LIBEVENT_CORE,
369 	[libevent_core >= 2],
370 	[
371 		AM_CPPFLAGS="$LIBEVENT_CORE_CFLAGS $AM_CPPFLAGS"
372 		CPPFLAGS="$AM_CPPFLAGS $SAVED_CPPFLAGS"
373 		LIBS="$LIBEVENT_CORE_LIBS $LIBS"
374 		found_libevent=yes
375 	],
376 	found_libevent=no
377 )
378 if test x$found_libevent = xno; then
379 	PKG_CHECK_MODULES(
380 		LIBEVENT,
381 		[libevent >= 2],
382 		[
383 			AM_CPPFLAGS="$LIBEVENT_CFLAGS $AM_CPPFLAGS"
384 			CPPFLAGS="$AM_CPPFLAGS $SAVED_CPPFLAGS"
385 			LIBS="$LIBEVENT_LIBS $LIBS"
386 			found_libevent=yes
387 		],
388 		found_libevent=no
389 	)
390 fi
391 if test x$found_libevent = xno; then
392 	AC_SEARCH_LIBS(
393 		event_init,
394 		[event_core event event-1.4],
395 		found_libevent=yes,
396 		found_libevent=no
397 	)
398 fi
399 AC_CHECK_HEADER(
400 	event2/event.h,
401 	AC_DEFINE(HAVE_EVENT2_EVENT_H),
402 	[
403 		AC_CHECK_HEADER(
404 			event.h,
405 			AC_DEFINE(HAVE_EVENT_H),
406 			found_libevent=no
407 		)
408 	]
409 )
410 if test "x$found_libevent" = xno; then
411 	AC_MSG_ERROR("libevent not found")
412 fi
413 
414 # libcrypto (via libssl for SHA information)
415 PKG_CHECK_MODULES(
416 	LIBCRYPTO,
417 	libcrypto,
418 	[
419 	 	AM_CFLAGS="$LIBCRYPTO_CFLAGS $AM_CFLAGS"
420 		CFLAGS="$AM_CFLAGS $SAVED_CFLAGS"
421 		LIBS="$LIBCRYPTO_LIBS $LIBS"
422 		found_libcrypto=yes
423 	],
424 	[
425 	 	found_libcrypto=no
426 	]
427 )
428 
429 if test "x$found_libcrypto" = "xyes"; then
430 	AC_DEFINE(HAVE_LIBCRYPTO)
431 fi
432 
433 AC_SEARCH_LIBS(uuid_create, , AC_DEFINE(HAVE_BSD_UUID))
434 AC_SEARCH_LIBS(uuid_create, found_uuid=no, found_uuid=yes)
435 AC_SEARCH_LIBS(mergesort, , AC_DEFINE(HAVE_BSD_MERGESORT))
436 
437 # Don't define HAVE_BSD_UUID on darwin (Apple) as this breaks the BSD API.
438 # Instead, use the UUID implementation wrapper that's in compat/ plus uuid
439 # ossp
440 if test "x$found_uuid" = "xyes" -a "x$PLATFORM" != "darwin"; then
441 	AC_DEFINE(HAVE_BSD_UUID)
442 else
443 	PKG_CHECK_MODULES(
444 		LIBUUID,
445 		uuid,
446 		[
447 			AM_CFLAGS="$LIBUUID_CFLAGS $AM_CFLAGS"
448 			CFLAGS="$AM_CFLAGS $SAVED_CFLAGS"
449 			LIBS="$LIBUUID_LIBS $LIBS"
450 			found_libuuid=yes
451 		],
452 		[
453 			found_libuuid=no
454 		]
455 	)
456 
457 	if test "x$found_libuuid" = "xno"; then
458 		AC_CHECK_HEADER(
459 			uuid.h,
460 			found_libuuid=yes,
461 			found_libuuid=no)
462 	fi
463 fi
464 
465 if test "x$found_libuuid" = "xno"; then
466 	AC_MSG_ERROR("*** couldn't find uuid ***")
467 fi
468 
469 PKG_CHECK_MODULES(
470 	ZLIB,
471 	zlib,
472 	[
473 	 	AM_CFLAGS="$ZLIB_CFLAGS $AM_CFLAGS"
474 		CFLAGS="$AM_CFLAGS $SAVED_CFLAGS"
475 		LIBS="$ZLIB_LIBS $LIBS"
476 		found_zlib=yes
477 	],
478 	[
479 	 	found_zlib=no
480 	]
481 )
482 
483 if test "x$found_zlib" = "xno"; then
484 	AC_CHECK_HEADER(
485 		zlib.h,
486 		,
487 		found_zlib=no)
488 fi
489 
490 if test "x$found_zlib" = "xno"; then
491 	AC_MSG_ERROR("*** couldn't find zlib ***")
492 fi
493 
494 if test "$PLATFORM" = "linux"; then
495 	PKG_CHECK_MODULES(
496 		LIBMD,
497 		libmd,
498 		[
499 			AM_CFLAGS="$LIBMD_CFLAGS $AM_CFLAGS"
500 			CFLAGS="$AM_CFLAGS $SAVED_CFLAGS"
501 			LIBS="$LIBMD_LIBS $LIBS"
502 		],
503 		[
504 			AC_MSG_ERROR("*** couldn't find libmd via pkg-config")
505 		]
506 	)
507 	PKG_CHECK_MODULES(
508 		LIBBSD,
509 		libbsd-overlay,
510 		[
511 			AM_CFLAGS="$LIBBSD_CFLAGS $AM_CFLAGS"
512 			CFLAGS="$AM_CFLAGS $SAVED_CFLAGS"
513 			LIBS="$LIBBSD_LIBS $LIBS"
514 			found_libbsd=yes
515 			AC_DEFINE(HAVE_LIBBSD)
516 		],
517 		[
518 			AC_MSG_ERROR("*** couldn't find libbsd-overlay via pkg-config")
519 		]
520 
521 	)
522 fi
523 
524 # Look for a suitable queue.h.  We hope libbsd is enough, but that is missing
525 # some declarations.
526 AC_CHECK_DECL(
527 	TAILQ_CONCAT,
528 	found_queue_h=yes,
529 	found_queue_h=no,
530 	[#include <sys/queue.h>]
531 )
532 AC_CHECK_DECL(
533 	TAILQ_PREV,
534 	,
535 	found_queue_h=no,
536 	[#include <sys/queue.h>]
537 )
538 AC_CHECK_DECL(
539 	TAILQ_FOREACH_SAFE,
540 	,
541 	found_queue_h=no,
542 	[#include <sys/queue.h>]
543 )
544 
545 if test "x$found_queue_h" = xyes; then
546 	AC_DEFINE(HAVE_QUEUE_H)
547 else
548 	AC_MSG_ERROR("*** sys/queue.h missing key defines ***)
549 fi
550 
551 AC_CHECK_DECL(
552 	RB_GENERATE_STATIC,
553 	found_sys_tree_h=yes,
554 	found_sys_tree_h=no,
555 	[#include <sys/tree.h>]
556 )
557 
558 if test "x$found_sys_tree_h" = xyes; then
559 	AC_DEFINE(HAVE_TREE_H)
560 else
561 	AC_MSG_NOTICE("Using compat/tree.h")
562 fi
563 
564 # Look for __progname.
565 AC_MSG_CHECKING(for __progname)
566 AC_LINK_IFELSE([AC_LANG_SOURCE(
567 	[
568 		#include <stdio.h>
569 		#include <stdlib.h>
570 		extern char *__progname;
571 		int main(void) {
572 			const char *cp = __progname;
573 			printf("%s\n", cp);
574 			exit(0);
575 		}
576 	])],
577 	[AC_DEFINE(HAVE___PROGNAME) AC_MSG_RESULT(yes)],
578 	AC_MSG_RESULT(no)
579 )
580 
581 PKG_CHECK_MODULES(
582 	LIBPANELW,
583 	panelw,
584 	found_panel=yes,
585 	found_panel=no
586 )
587 
588 PKG_CHECK_MODULES(
589 	LIBPANELW,
590 	gnupanelw,
591 	found_panel=yes,
592 	found_panel=no
593 )
594 
595 PKG_CHECK_MODULES(
596 	LIBPANELW,
597 	panel,
598 	found_panel=yes,
599 	found_panel=no
600 )
601 if test "x$found_panel" = "xno"; then
602 	AC_CHECK_LIB(panelw, update_panels, [],
603 		AC_MSG_ERROR([ "*** panelw not found for ncurses. ***"]),
604 		[-lncurses]
605 	)
606 
607 	LIBPANELW_LIBS="-lpanelw"
608 fi
609 
610 PKG_CHECK_MODULES(
611 	LIBNCURSES,
612 	ncursesw,
613 	found_ncurses=yes,
614 	found_ncurses=no
615 )
616 if test "x$found_ncurses" = xyes; then
617 	AM_CFLAGS="$LIBNCURSES_CFLAGS $LIBTINFO_CFLAGS $LIBPANELW_CFLAGS $AM_CFLAGS"
618 	CFLAGS="$LIBNCURSES_CFLAGS $LIBTINFO_CFLAGS $LIBPANELW_CFLAGS $CFLAGS"
619 	LIBS="$LIBNCURSES_LIBS $LIBTINFO_LIBS $LIBPANELW_LIBS $LIBS"
620 else
621 	AC_CHECK_LIB(
622 		ncursesw,
623 		setupterm,
624 		found_ncurses=yes,
625 		found_ncurses=no
626 	)
627 	if test "x$found_ncurses" = xyes; then
628 		AC_CHECK_HEADER(
629 			ncurses.h,
630 			AM_CFLAGS="$LIBPANELW_CFLAGS $AM_CFLAGS"
631 			CFLAGS="$LIBPANEL_CFLAGS $CFLAGS"
632 			LIBS="$LIBS -lncursesw $LIBPANELW_LIBS",
633 			found_ncurses=no
634 		)
635 	fi
636 fi
637 if test "x$found_ncurses" = xyes; then
638 	AC_DEFINE(HAVE_NCURSES_H)
639 else
640 	# No ncurses, try curses.
641 	AC_CHECK_LIB(
642 		cursesw,
643 		setupterm,
644 		found_curses=yes,
645 		found_curses=no
646 	)
647 	AC_CHECK_HEADER(
648 		curses.h,
649 		,
650 		found_curses=no)
651 	if test "x$found_curses" = xyes; then
652 		AM_CFLAGS="$LIBPANELW_CFLAGS $AM_CFLAGS"
653 		CFLAGS="$LIBPANEL_CFLAGS $CFLAGS"
654 		LIBS="$LIBS -lcursesw $LIBPANELW_LIBS"
655 		AC_DEFINE(HAVE_CURSES_H)
656 	else
657 		AC_MSG_ERROR("curses not found")
658 	fi
659 fi
660 
661 # Save our CFLAGS/CPPFLAGS/LDFLAGS for the Makefile and restore the old user
662 # variables.
663 AC_SUBST(AM_CPPFLAGS)
664 CPPFLAGS="$SAVED_CPPFLAGS"
665 AC_SUBST(AM_CFLAGS)
666 CFLAGS="$SAVED_CFLAGS"
667 AC_SUBST(AM_LDFLAGS)
668 LDFLAGS="$SAVED_LDFLAGS"
669 
670 AC_CONFIG_FILES([Makefile
671 		 compat/Makefile
672 		 libexec/Makefile
673 		 libexec/got-read-tree/Makefile
674 		 libexec/got-fetch-pack/Makefile
675 		 libexec/got-index-pack/Makefile
676 		 libexec/got-read-blob/Makefile
677 		 libexec/got-read-commit/Makefile
678 		 libexec/got-read-gitconfig/Makefile
679 		 libexec/got-read-gotconfig/Makefile
680 		 libexec/got-read-object/Makefile
681 		 libexec/got-read-pack/Makefile
682 		 libexec/got-read-patch/Makefile
683 		 libexec/got-read-tag/Makefile
684 		 libexec/got-send-pack/Makefile
685 		 got/Makefile
686 		 gotadmin/Makefile
687 		 gotwebd/Makefile
688 		 template/Makefile
689 		 tog/Makefile
690 		 Makefile.common:Makefile.common.in])
691 AC_OUTPUT
692 
693 executables="$(eval echo ${exec_prefix}/bin)"
694 helpers="$(eval echo ${libexecdir})"
695 manpages="$(eval echo ${mandir})"
696 
697 echo "
698 Configured got-portable with:
699 
700  Version:      $VERSION
701 
702  Prefix:       ${prefix}
703  Executables:  ${executables}
704  Helpers:      ${helpers}
705  Man pages:    ${manpages}
706 "